اضافه کردن دکمه به تاس در آردوینو

 اکنون که ما می دانیم که چطور با دکمه های فشاری کار کنیم، دیگر مجبور نیستیم از دکمه ی reset آردوینو برای کنترل تاس استفاده کنیم. و به جای آن، حالا دکمه ی فشاری خودمان را به بردبرد اضافه می کنیم. همان طور که در تصویر 12 مشاهده می کنید، ما برای تاس باینری از دکمه ی فشاری خودمان استفاده می کنیم. اما برای این کار نیاز داریم تا مدار فعلی خود را کمی تغییر دهیم. در حقیقت، ما مجبور نیستیم قطعات موجود را به هیچ وجه تغییر دهیم، بلکه تنها نیاز داریم برخی چیزها را تغییر دهیم. ابتدا، ما یک دکمه را در برد برد قرار می دهیم و آن را به پین 7 متصل می کنیم. سپس این دکمه را از طریق یک مقاومت 10kΩ به اتصال به زمین(ground ) متصل می کنیم و از یک تکه سیم برای متصل کردن پایه ی دیگر دکمه  به پین 5 ولت استفاده می کنیم. تمام تغییرات سخت افزاری که نیاز داشتیم همین بود. در زیر نرم افزار این کار را مشاهده می کنید:

const unsigned int LED_BIT0 = 12;
const unsigned int LED_BIT1 = 11;
const unsigned int LED_BIT2 = 10;
const unsigned int BUTTON_PIN = 7;

void setup() {
  pinMode(LED_BIT0, OUTPUT);
  pinMode(LED_BIT1, OUTPUT);
  pinMode(LED_BIT2, OUTPUT);  
  pinMode(BUTTON_PIN, INPUT);  
  randomSeed(analogRead(A0));
}
int current_value = 0;
int old_value = 0;
void loop() {
  current_value = digitalRead(BUTTON_PIN);
  if (current_value != old_value && current_value == HIGH) {
    output_result(random(1, 7));
    delay(50);
  }
  old_value = current_value;
}
void output_result(const long result) {
  digitalWrite(LED_BIT0, result & B001);
  digitalWrite(LED_BIT1, result & B010);
  digitalWrite(LED_BIT2, result & B100);
}

(تصویر 12: تاس باینری ما که از دکمه ی خودش استفاده می کند)

 این یک ادغام عالی بود از کد اصلی و کدهایی که نیاز داشتیم تا یک دکمه ی پرش زدایی شده را کنترل کنیم. مثل همیشه، ما تمام پین هایی که استفاده می کنیم را مقدار دهی اولیه(initialize ) می کنیم: سه پین خروجی(output ) برای ال ای دی ها، و یک پین ورودی(input ) برای دکمه. ما همچنین seed تصادفی را نیز مقدار دهی اولیه(initialize ) می کنیم و در تابع loop برای فشارهای وارد شده به دکمه، صبر می کنیم. هنگامی که دکمه ی ما فشار داده می شود، گویی ما تاس را می اندازیم، و نتیجه را در ال ای دی ها بعنوان خروجی مشاهده می کنیم. اکنون ما با موفقیت دکمه ی دلخواه خود را جایگزین دکمه ی reset کردیم. حالا که می دانیم چقدر ساده است که یک دکمه را اضافه کنیم، می خواهیم در بخش بعدی، یک دکمه ی دیگر را نیز برای تبدیل کردن تاس ساده ی خود به یک بازی دونفره اضافه می کنیم.

 {module کمک نقدی به نویسنده}